bb.donnay-software.com

Code: Select all

//-----------------------------------------------------------------------------
// This function is the entry point into the TimeClock app
//
WEBPROC Login() PATH TC
   GETVAR UID AS cUID
   GETVAR PWD AS cPWD
   Local lUpdate  := .t.
   Local cMessage := ""
   Local oServer  := oClient:Parent  // this is the xbHTTPServer object
   Local nID

   oClient:CloseSession()

   debug( "TC_Login 1: SID", oClient:GetSessionHandle(), "# Sess", xbSession():ActiveSessions(), "CARGO", oClient:GetCargo())

   if Empty(cUID)
      // no user ID specified - redisplay login screen
      oClient:SendFile( oServer:RootDir + "\TC\Login.htm" )
      Return
   endif

   OpenDBF( "EMPLOYEE", "EMP", "EMPLOYEE")

   nID := Val(cUID)

   if !(DbSeek(nID, .f.) .and. Upper(Trim(emp->password)) == Upper(Trim(cPWD)))
      // invalid userid/password - go back to login screen
      dbCLoseAll()
      oClient:SendFile( oServer:RootDir + "\TC\Login.htm" )
      Return
   endif

   // we have a valid userid/password

   // make sure any previous session is properly closed
   oClient:CloseSession()

   // the GetCargo/SetCargo methods will automatically open a new session to keep track of this guy

   if oClient:GetCargo("UID") != NIL
      if oClient:GetCargo("UID") == nID
         // same guy, don't update login count in password table
         lUpdate := .f.
      else
         // this client was previously logged in under a different userid
         // close the old session
         oClient:CloseSession()
      endif
   endif

   oClient:SetCargo("UID"       , nID)
   oClient:SetCargo("NAME"      , AllTrim(emp->MName + " " + Trim(emp->FName) + " " + emp->LName))
   oClient:SetCargo("SECURITY"  , emp->security)  // save the security level
   oClient:SetCargo("EXCEPTIONS", emp->(GetExceptions()))

   if emp->DATE_IN == date()
      oClient:SetCargo("CLOCKIN" , emp->time_in)
   endif

   if emp->DATE_OUT == date() .and. emp->time_out >= emp->time_in
      oClient:SetCargo("CLOCKOUT", emp->time_out)
   endif

   // update the login count if user was not already logged in
   if lUpdate .and. dbRLock()
      emp->nLogins   := emp->nLogins + 1
      emp->LogInDate := date()
      emp->LogInTime := time()
   endif

   dbCLoseAll()

   debug( "TC_Login 2: SID", oClient:GetSessionHandle(), "# Sess", xbSession():ActiveSessions(), "CARGO", oClient:GetCargo())

   // attach the response string to the HTTP response object
   oClient:HTTPResponse:Content := DrawOuterFrame( oClient:GetSessionHandle() )

   Return