bb.donnay-software.com

Code: Select all

FUNCTION DC_DbSeek(cKey, lSoftseek, cIndexTag, lSeekLast, xDataSource )

LOCAL lFound := .f.
LOCAL xScopeTop, xScopeBot
LOCAL lExact, xValue, i, xCargo
LOCAL aScopeArray := DC_SetScopeArray()
LOCAL cDataType := Valtype(xDataSource)

IF cDataType == 'O' // It's an SQLexpress cursor

  lFound := xDataSource:seek( cKey, lSoftSeek )
  IF DC_IsSQLCargo( xDataSource, @xCargo )
    xCargo[DCSQL_CARGO_FOUND] := lFound
  ENDIF
  RETURN lFound

ELSEIF cDataType == 'N' // It's an ADS SQL cursor
  // AdsSeek( nIndex, @cKey, cLength, nDataType, nSeekType, @lFound )
  RETURN .F.

ELSEIF DC_ScopeAds() .AND. _SetRdd()='ADSDBE'
//roger
  RETURN dbSeek( cKey, lSoftSeek, cIndexTag, lSeekLast )

ENDIF

IF !Empty(aScopeArray)
  FOR i := 1 TO Len(aScopeArray)
    IF Valtype(aScopeArray[i]) = 'A'
      GOTO aScopeArray[i,1]
    ELSE
      GOTO aScopeArray[i]
    ENDIF
    IF &(IndexKey(0)) = cKey
      DC_SetScopeArrayPointer(i)
      RETURN .T.
    ELSEIF lSoftSeek .AND. &(IndexKey(0)) > cKey                 // <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
      DC_SetScopeArrayPointer(i)                                 // <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
      RETURN .F.                                                 // <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< 
    ENDIF
  NEXT
  GO BOTTOM
  SKIP
  RETURN .F.
ELSEIF !DC_ScopeExpress()
  lExact := Set(_SET_EXACT,.f.)
  xValue := _DbSeek( cKey, lSoftSeek, cIndexTag, lSeekLast )
  Set(_SET_EXACT,lExact)
  RETURN xValue
ENDIF

lExact := Set(_SET_EXACT,.f.)
DEFAULT lSoftseek := Set(_SET_SOFTSEEK)

* perform the Xbase seek first
  lFound := _DbSeek(cKey, lSoftseek, cIndexTag, lSeekLast )

* set DC_Bof, DC_Eof
  DC_Eof(eof())
  DC_Bof(bof())

* Roger: return only after setting DC_Eof(), DC_Bof()
* IF !lFound   // Roger: Xbase is changed, can no longer trust this flag.
  IF eof()
    Set(_SET_EXACT,lExact)
    RETURN .f. // lFound : Note: I think that suits most cases.
  ENDIF

  xScopeTop := DC_SetScope( 0 )
  xScopeBot := DC_SetScope( 1 )

  IF Valtype(xScopeTop)#'U' .AND. _ScopeKey( xScopeTop ) < xScopeTop
    * IF Set(_SET_SOFTSEEK)  //  possible bug??
    IF Set(_SET_SOFTSEEK) .OR. lSoftSeek
      DC_DbGoTop()
    ELSE
      _dbGoBottom()
      _dbSkip()
      DC_Eof(.t.)       // Roger: should set this ??
    ENDIF
  ELSEIF Valtype(xScopeBot)#'U' .AND. _ScopeKey( xScopeBot ) > xScopeBot
    _dbGoBottom()
    _dbSkip()
    DC_Eof(.t.)         // Roger: should set this ??
  ENDIF

  lFound := ! DC_Eof()

Set(_SET_EXACT,lExact)

RETURN lFound