bb.donnay-software.com

Code: Select all

/*

This example shows how to use DC_KeyOrder() to determine
if a browse column is an "indexed column" and can be
sorted.  Indexed columns use the SORT clause of DCBROWSECOL
to color sortable columns blue and sorted columns red.

*/

#INCLUDE "dcdialog.CH"

FUNCTION Main()

LOCAL GetList[0], GetOptions, i, oBrowse, aStruct, nKeyOrder, bSort, ;
      cFieldName, bEval, bField, aSort

aSort := DC_BrowseSort()
aSort[9] := '11.Lucida Console Bold Italic'
aSort[10] := '11.Lucida Console Italic'
aSort[11] := '10.Lucida Console'

DC_LoadRdds()

USE ..\..\data\customer INDEX ..\..\data\customer VIA 'FOXCDX'

aStruct := CUSTOMER->(dbStruct())

@ 0,0 DCBROWSE oBrowse SIZE 100, 20 ;
      PRESENTATION DC_BrowPres() ;
      USEVISUALSTYLE ;
      SORTSFONT '11.Lucida Console Bold Italic' ;
      SORTUFONT '11.Lucida Console Italic' ;
      SORTNFONT '10.Lucida Console'

FOR i := 1 TO Len(aStruct)

  cFieldName := aStruct[i,1]

  nKeyOrder := CUSTOMER->(DC_KeyOrder(cFieldName))

  IF nKeyOrder > 0
    bSort := _SortBlock(nKeyOrder)
  ELSE
    bSort := nil
  ENDIF

  bField := FieldWBlock(cFieldName,'CUSTOMER')
  DCBROWSECOL DATA bField ;
      HEADER cFieldName WIDTH aStruct[i,3] PARENT oBrowse ;
      SORT bSort _DEFAULT i==3

NEXT

DCREAD GUI FIT TITLE 'Browse with Sort' SETAPPWINDOW

RETURN nil

* --------------

STATIC FUNCTION _SortBlock( nKeyOrder )

RETURN {||CUSTOMER->(OrdSetFocus(nKeyOrder))}

* -------------

PROC appsys
RETURN