bb.donnay-software.com

Code: Select all

#INCLUDE "dcdialog.CH"

#DEFINE adCmdText  1

#Pragma Library("ascom10.lib")

FUNCTION Main

LOCAL oADOConnection, oADORecordset, oADOFields, oADOField, value

// Creating the wrapping class instance for the ADO connection.
oADOConnection := ActiveXObject():create('ADODB.Connection')

// Opening the ADO connection, targeting an Access database.
oADOConnection:ConnectionString := ;
   "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="+DC_CurPath()+"\BookSale.mdb"

oADOConnection:Open()

// Creating a new ADO Recordset
oADORecordset := ActiveXObject():create('ADODB.Recordset')

// Filling the ADO RecordSet with the result of an SQL request executed through the newly opened ADO connection
oADORecordset:Open("SELECT * FROM Publishers ORDER BY Name",oADOConnection,,,adCmdText)

oADORecordset:MoveFirst()
DO WHILE .NOT. oADORecordset:EOF
  // Obtaining the 'Name' field value of the current record
  value := oADORecordset:Fields("Name"):Value
  // Dumping the field value to the screen
  ? "oADORecordset:Fields('Name'):Value=" + value
  // Move to the next record
  oADORecordset:MoveNext()
ENDDO

// Required: release the ADO RecordSet ActiveX
oADORecordset:Destroy()

// Required: close and release the ADO Connection ActiveX
oADOConnection:Close()
oADOConnection:Destroy()

wait

return nil