Build 2.00.2307

[rdonnay]

I updated _DCXBROW.PRG to use the new hide() and show() methods.
http://bb.donnay-software.com/donnay/_dcxbrow2307.zip

This sample program should now work:

Code: Select all

#INCLUDE "dcdialog.CH"
#INCLUDE "Directry.CH"

// This example shows how to use the new hide() and show() methods of XbpColumn class,
// by using the DCBROWSECOL .. HIDE clause,
// when using Xbase++ build 2307 or later and eXpress++ build 269 or later.

]FUNCTION Main()

LOCAL GetList[0], oBrowse, aDir, oSayColumns, lHideWriteDate := .f., ;
      lHideCreateDate := .f., lHideAccessdate := .f.

aDir := Directory()

@ 0,0 DCSAY '#columns:'
@ DCGUI_ROW, DCGUI_COL + 10 DCSAY {||IIF(Valtype(oBrowse)='O',oBrowse:colCount,0)} SIZE 10 ;
   FONT '10.Lucida Console' SAYOBJECT oSayColumns

@ 1,0 DCBROWSE oBrowse DATA aDir FONT '10.Lucida Console' SIZE 100,20 HEADLINES 2 FIT

DCBROWSECOL ELEMENT F_NAME HEADER 'File Name' WIDTH 20 PARENT oBrowse

DCBROWSECOL ELEMENT F_SIZE HEADER 'Size' WIDTH 10 PARENT oBrowse

DCBROWSECOL ELEMENT F_WRITE_DATE HEADER 'Write;Date' WIDTH 10 PARENT oBrowse ;
   HIDE {||lHideWriteDate}

DCBROWSECOL ELEMENT F_WRITE_TIME HEADER 'Write;Time' WIDTH 10 PARENT oBrowse

DCBROWSECOL ELEMENT F_ATTR HEADER 'Attr' WIDTH 5 PARENT oBrowse

DCBROWSECOL ELEMENT F_CREATION_DATE HEADER 'Creation;Date' WIDTH 10 PARENT oBrowse ;
  HIDE {||lHideCreateDate}

DCBROWSECOL ELEMENT F_CREATION_TIME HEADER 'Creation;Time' WIDTH 10 PARENT oBrowse

DCBROWSECOL ELEMENT F_ACCESS_DATE HEADER 'Access;Date' WIDTH 10 PARENT oBrowse ;
  HIDE {||lHideAccessDate}

DCBROWSECOL ELEMENT F_ACCESS_TIME HEADER 'Access;Time' WIDTH 10 PARENT oBrowse

@ 22,0 DCPUSHBUTTON CAPTION 'Toggle Write Date' SIZE 15,1.2 ;
        ACTION {||lHideWriteDate := !lHideWriteDate, ;
                  DC_GetRefresh(GetList), ;
                  oSayColumns:refresh()}

@ DCGUI_ROW, DCGUI_COL + 20 DCPUSHBUTTON CAPTION 'Toggle Create Date' SIZE 15,1.2 ;
        ACTION {||lHideCreateDate := !lHideCreateDate, ;
                  DC_GetRefresh(GetList), ;
                  oSayColumns:refresh()}

@ DCGUI_ROW, DCGUI_COL + 20 DCPUSHBUTTON CAPTION 'Toggle Access Date' SIZE 15,1.2 ;
        ACTION {||lHideAccessDate := !lHideAccessDate, ;
                  DC_GetRefresh(GetList), ;
                  oSayColumns:refresh()}

DCREAD GUI FIT TITLE 'Browse Column Hide/Show Test' ;
   EVAL {||oSayColumns:refresh()}

RETURN nil

* -----------

PROC appsys ; return

[Tom]

Thanks! I'll check this out.